Take a fresh look at your lifestyle.

Hàm IF trong Excel giữa hai số hoặc ngày tháng

78
Rate this post

Hướng dẫn cho biết cách sử dụng hàm IF trong Excel để xem liệu một số hoặc ngày nhất định có nằm giữa hai giá trị hay không.

Để kiểm tra xem một giá trị đã cho có nằm giữa hai giá trị số hay không, bạn có thể sử dụng hàm AND với hai phép thử logic. Để trả về giá trị của riêng bạn khi cả hai biểu thức đều đánh giá là TRUE, hãy lồng AND vào bên trong hàm IF. Ví dụ chi tiết theo sau.

Ví Dụ Về Hàm IF

excel-if-between

Sử Dụng Hàm IF trong Excel: Kết hợp với giá trị lớn nhỏ

Để kiểm tra xem một số nhất định có nằm giữa hai số mà bạn chỉ định hay không, hãy sử dụng hàm AND với hai phép thử logic:

  • Sử dụng toán tử (>) lớn hơn để kiểm tra xem giá trị có cao hơn một số nhỏ hơn không.
  • Sử dụng toán tử nhỏ hơn (<) để kiểm tra xem giá trị có nhỏ hơn một số lớn hơn hay không.

Giá trị chung nếu giữa công thức là:

AND ( value > small_number , value < large_number )

Để bao gồm các giá trị biên, hãy sử dụng các toán tử lớn hơn hoặc bằng (> =) và nhỏ hơn hoặc bằng (<=):

AND ( value > = small_number , value <= large_number )

Ví dụ: để xem liệu một số trong A2 có nằm trong khoảng từ 10 đến 20, không bao gồm các giá trị ranh giới hay không, công thức trong B2, được sao chép xuống, là:

=AND(A2>10, A2<20)

Để kiểm tra xem A2 có nằm trong khoảng từ 10 đến 20 hay không, bao gồm các giá trị ngưỡng, công thức trong C2 có dạng sau:

=AND(A2>=10, A2<=20)

Trong cả hai trường hợp, kết quả là giá trị Boolean TRUE nếu số được kiểm tra nằm trong khoảng từ 10 đến 20, FALSE nếu không phải là:

Hàm IF AND

Trong trường hợp bạn muốn trả về giá trị tùy chỉnh nếu một số nằm giữa hai giá trị, thì hãy đặt công thức AND trong phép thử logic của hàm IF .

Ví dụ: để trả về “Có” nếu số trong A2 từ 10 đến 20, “Không” nếu không, hãy sử dụng một trong các câu lệnh IF sau:

Nếu từ 10 đến 20:

=IF(AND(A2>10, A2<20), “Yes”, “No”)

Nếu từ 10 đến 20, bao gồm các ranh giới:

=IF(AND(A2>=10, A2<=20), “Yes”, “No”)

Mẹo. Thay vì mã hóa cứng các giá trị ngưỡng trong công thức, bạn có thể nhập chúng vào các ô riêng lẻ và tham khảo các ô đó như được hiển thị trong ví dụ bên dưới.

Giả sử bạn có một tập hợp các giá trị trong cột A và muốn biết giá trị nào nằm giữa các số trong cột B và C trong cùng một hàng. Giả sử một số nhỏ hơn luôn nằm trong cột B và một số lớn hơn nằm trong cột C, nhiệm vụ có thể được thực hiện với công thức sau:

=IF(AND(A2>B2, A2<C2), “Yes”, “No”)

Bao gồm các ranh giới:

=IF(AND(A2>=B2, A2<=C2), “Yes”, “No”)

Và đây là một biến thể của câu lệnh If between trả về một giá trị chính nó nếu TRUE, một số văn bản hoặc một chuỗi trống nếu FALSE:

=IF(AND(A2>10, A2<20), A2, “Invalid”)

Bao gồm các ranh giới:

=IF(AND(A2>=10, A2<=20), A2, “Invalid”)

Hàm if kết hợp Mid và Max

Khi các số nhỏ hơn và lớn hơn mà bạn đang so sánh có thể xuất hiện trong các cột khác nhau (tức là số 1 không phải lúc nào cũng nhỏ hơn số 2), hãy sử dụng phiên bản công thức phức tạp hơn một chút.

AND ( giá trị > MIN ( num1 , num2 ), giá trị <MAX ( num1 , num2 ))

Ở đây, trước tiên chúng ta kiểm tra xem giá trị đích có cao hơn một trong hai số được trả về bởi hàm MIN hay không, sau đó kiểm tra xem nó có thấp hơn một trong hai số được trả về bởi hàm MAX hay không .

Để bao gồm các số ngưỡng, hãy điều chỉnh logic như sau:

AND ( giá trị > = MIN ( num1 , num2 ), giá trị <= MAX ( num1 , num2 ))

Ví dụ: để tìm hiểu xem một số trong A2 có nằm giữa hai số trong B2 và C2 hay không, hãy sử dụng một trong các công thức sau:

Loại trừ ranh giới:

=AND(A2>MIN(B2, C2), A2<MAX(B2, C2))

Bao gồm các ranh giới:

=AND(A2>=MIN(B2, C2), A2<=MAX(B2, C2))

Để trả về các giá trị của riêng bạn thay vì TRUE và FALSE, hãy sử dụng câu lệnh IF trong excel giữa hai số sau:

=IF(AND(A2>MIN(B2, C2), A2<MAX(B2, C2)), “Yes”, “No”)

Hoặc

=IF(AND(A2>=MIN(B2, C2), A2<=MAX(B2, C2)), “Yes”, “No”)

Hàm IF Trong Excel: điều kiện ngày tháng

Hàm If điều kiện ngày tháng trong Excel về cơ bản giống như If giữa các số .

Để kiểm tra xem một ngày nhất định có nằm trong một phạm vi nhất định hay không, công thức chung là:

IF (AND ( date > = start_date , date <= end_date ), value_if_true, value_if_false)

Không bao gồm các ngày ranh giới:

IF (AND ( date > start_date , date < end_date ), value_if_true, value_if_false)

Tuy nhiên, có một lưu ý: IF không nhận ra ngày được cung cấp trực tiếp cho các đối số của nó và coi chúng là chuỗi văn bản. Để IF nhận ra một ngày, nó phải được bao bọc trong hàm DATEVALUE .

Ví dụ: để kiểm tra xem một ngày trong A2 có nằm trong khoảng từ 1 tháng 1 năm 2022 đến 31 tháng 12 năm 2022 hay không, bạn có thể sử dụng công thức này:

=IF(AND(A2>=DATEVALUE(“1/1/2022”), A2<=DATEVALUE(“12/31/2022”)), “Yes”, “No”)

Trong trường hợp, ngày bắt đầu và ngày kết thúc nằm trong các ô được xác định trước, công thức trở nên đơn giản hơn nhiều:

=IF(AND(A2>=$E$2, A2<=$E$3), “Yes”, “No”)

Trong đó $ E $ 2 là ngày bắt đầu và $ E $ 3 là ngày kết thúc. Vui lòng lưu ý việc sử dụng tham chiếu tuyệt đối để khóa địa chỉ ô, vì vậy công thức sẽ không bị hỏng khi được sao chép vào các ô bên dưới.

Mẹo. Nếu mỗi ngày được kiểm tra phải nằm trong phạm vi riêng của nó và các ngày ranh giới có thể được hoán đổi cho nhau, thì hãy sử dụng hàm MIN và MAX để xác định ngày nhỏ hơn và lớn hơn như được giải thích trong Nếu giá trị ranh giới nằm trong các cột khác nhau .

Hàm IF ngày trong vòng N ngày tới

Để kiểm tra xem một ngày có nằm trong vòng n ngày tiếp theo kể từ ngày hôm nay hay không, hãy sử dụng hàm TODAY để xác định ngày bắt đầu và ngày kết thúc. Bên trong câu lệnh AND, kiểm tra logic đầu tiên kiểm tra xem ngày đích có lớn hơn ngày hôm nay hay không, trong khi kiểm tra logic thứ hai kiểm tra xem nó có nhỏ hơn hoặc bằng ngày hiện tại cộng với n ngày hay không:

IF (AND ( date > TODAY (), date <= TODAY () + n ), value_if_true, value_if_false)

Ví dụ: để kiểm tra xem một ngày trong A2 có xảy ra trong 7 ngày tới hay không, công thức là:

=IF(AND(A2>TODAY(), A2<=TODAY()+7), “Yes”, “No”)

Hàm IF ngày trong vòng N ngày qua

Để kiểm tra xem một ngày nhất định có nằm trong vòng n ngày cuối cùng của ngày hôm nay hay không, bạn lại sử dụng IF cùng với các hàm AND và TODAY. Bài kiểm tra logic đầu tiên của AND kiểm tra xem ngày được kiểm tra có lớn hơn hoặc bằng ngày hôm nay trừ n ngày hay không và bài kiểm tra logic thứ hai sẽ kiểm tra xem ngày đó có nhỏ hơn ngày hôm nay hay không:

IF (AND ( date > = TODAY () – n , date <TODAY ()), value_if_true, value_if_false)

Ví dụ: để xác định xem một ngày trong A2 có xảy ra trong 7 ngày qua hay không, công thức là:

=IF(AND(A2>=TODAY()-7, A2<TODAY()), “Yes”, “No”)

Hy vọng rằng các ví dụ của chúng tôi đã giúp bạn hiểu cách sử dụng công thức If giữa trong Excel một cách hiệu quả. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!

=>> Nếu bạn đang làm về mảng kế toán bạn có thể xem Các hàm excel hay sử dụng trong kế toán

 

Bạn cũng có thể thích